Unreal Tournament — Создание простого мутатора на примере Vampire | Creating a simple mutator using the example of Vampire

1. В папке UnrealTournament (там где находятся папки System, Maps, Textures и т.д.) создаём свою папку с названием нашего мутатора. Именно с таким названием будет создан наш U-файл или по-другому пакадж. В нашем случае имя папки будет, например, Vampire.
2. В папке Vampire создаём папку Classes. В этой папке будут храниться наши файлы скриптов (UC-файлы).
3. Теперь необходимо сообщить UCC.exe, что скрипты, лежащие в папке Vampire должны быть скомпилированы. Для этого в файле UnrealTournament.ini, находящемся в UnrealTournament/System, нужно дописать строчку
   

   EditPackages=Vampire

   после других строчек, начинающихся с EditPackages, в конце секции [Editor.EditorEngine].

1. В папке Vampire создайте папку General (это может быть любое название, но пусть это будет General - общая).
2. В папке General создайте BAT-файл с именем compile.bat, откройте его и впишите такие строки:
   

   cd ..
   cd ..
   cd System
   del Vampire.u
   ucc make

   Это обеспечит нам переход в папку UnrealTournament/System, удаление старой версии нашего мутатора и запуск UCC.exe с параметром Make. Рекомендую в свойствах нашего BAT-файла убрать флажок «Закрывать окно по завершении сеанса работы», так как нам нужно видеть какие ошибки возникли в процессе компиляции.
3. В папке Vampire создайте ярлык на наш BAT-файл. Это просто для удобства. Советую назвать ярлык COMPILE и поставить ему какую-нибудь приметную иконку.
4. В папке Vampire создайте два ярлыка на UnrealTournament.exe и назовите их, например, DM-Deck16][ и CTF-Face.
5. В свойствах ярлыка DM-Deck16][ в поле ввода “Обьект” после указанного пути к программе введите следующее:
   

   DM-Deck16][.unr?mutator=Vampire.Vampire

6. Это может, например, выглядеть так:
   

   "C:\Program Files\GT Interactive\UnrealTournament\System\ UnrealTournament.exe" DM-Deck16][.unr?mutator=Vampire.Vampire

7. Примерно также поступим с ярлыком CTF-Face. В свойствах ярлыка CTF-Face в поле ввода “Обьект” после указанного пути к программе введите следующее:
   

   CTF-Face.unr?game=Botpack.CTFGame?mutator=Vampire.Vampire

8. Это может, например, выглядеть так:
   

   "C:\Program Files\GT Interactive\UnrealTournament\System\ UnrealTournament.exe" CTF-Face.unr?game=Botpack.CTFGame? mutator=Vampire.Vampire

9. Данные операции дадут нам возможность быстро запускать игру на картах DM-Deck16][ и CTF-Face с нашим мутатором. Иногда необходимо проверять мутаторы на разных типах игры. Это два ярлыка позволяют это делать для DeathMatch и CaptureTheFlag.

UnrealTournament (ПАПКА)
       |
       |- Vampire (ПАПКА)
                 |
                 |-COMPILE (ярлык на compile.bat)
                 |
                 |-DM-Deck16][ (ярлык)
                 |
                 |-CTF-Face (ярлык)
                 |
                 |-General (ПАПКА)
                 |      |
                 |      |-compile.bat (файл)
                 |
                 |-Classes (ПАПКА)

//===================================
// Vampire ; This is mutator script.
// Description: You gain life equal to the amount of damage you do to
// an enemy.
//===================================

class Vampire expands Mutator;

var bool Initialized;

var() float LifeStolenPerHit;
var() int MaxLife;
var() bool bInflictedDamageOnly;

function PostBeginPlay()
{
if (Initialized)
return;
Initialized = True;
Level.Game.RegisterDamageMutator( Self );
}

function MutatorTakeDamage( out int ActualDamage, Pawn Victim, Pawn InstigatedBy, out Vector HitLocation,
out Vector Momentum, name DamageType)
{
if ((InstigatedBy.IsA('Bot') || InstigatedBy.IsA('PlayerPawn')) && (Victim != InstigatedBy) && (InstigatedBy != None) && (Victim != None))
{
if ((Victim.Health < ActualDamage) && bInflictedDamageOnly)
ActualDamage = Victim.Health;
InstigatedBy.Health += ActualDamage * LifeStolenPerHit;

if ((InstigatedBy.Health > MaxLife) && (MaxLife != 0))
{
InstigatedBy.Health = MaxLife;
}
}

if ( NextDamageMutator != None )
NextDamageMutator.MutatorTakeDamage( ActualDamage, Victim, InstigatedBy, HitLocation, Momentum, DamageType );
}

defaultproperties
{
LifeStolenPerHit=1.000000
MaxLife=200
bInflictedDamageOnly=True
}

//===================================
// Vampire ; This is mutator script.
// Description: You gain life equal to the amount of damage you do to
// an enemy.
//===================================

class Vampire expands Mutator;

• Abstract – данный класс не может быть вызван (spawned), так как является базовым;
• Config – значения переменных данного класса сохраняются во внешнем конфигурационном файле. Если после этого ключевого слова стоят скобки с каким либо текстом в них, то значения переменных будут сохраняться в INI-файле с именем, стоящим в скобках. В противном случае (если в скобках ничего нет) значения переменных будут сохраняться в файле UnrealTournament.ini, который используется для этого по умолчанию;
• NoUserCreate – данный класс не может быть помещён на уровень с помощью UnrealEd;
• Native – некоторые фрагменты данного класса описаны с использованием внешнего программирования (импорт функций из библиотек DLL);
• NativeReplication – переменные данного класса полностью описаны с использованием внешнего программирования;
• SafeReplace – означает, что ссылка на этот класс может быть изменена на Null (пустая ссылка) или на значение по умолчанию, если данный класс не найден ни в одном из пакаджей. Пакаджи сами по себе не имеют свойства SafeReplace. Например вы в редакторе сделали свою карту с применением двух текстур MyTex1 и MyTex2 из пакаджа MyTextures.utx, а потом сохранили.
  • Если теперь вы удалите из пакаджа MyTextures.utx текстуру MyTex1, то на вашей карте те грани, на которые была наложена текстура MyTex1, покроются другой текстурой (той, которая выбрана по умолчанию) и карта всё равно будет запускаться. Но если теперь удалить сам пакадж MyTextures.utx и запустить карту, то игра выдаст сообщение об ошибке: «Пакадж MyTextures.utx не найден»;
• Within <Класс> - обьекты данного класса могут быть созданы только внутри указанного Класса (это не работает для UnrealTournament v 420);
• PerObjectConfig – информация о каждом обьекте данного класса должна храниться в конфигурационном файле отдельно под секцией с названием, зависящим от его (обьекта) имени. Смотри описание ключевого слова Config;
• Transient – данный класс не включается при сохранении игрового соcтояния (в Unreal);
• NoExport – не экспортировать в заголовок C++. Исполнение через командную строчку "UCC.exe Make -h" не будет генерировать автоматически заголовок C++ для функций и событий, описанных с помощью внешнего программирования.

var bool Initialized;

var() float LifeStolenPerHit;
var() int MaxLife;
var() bool bInflictedDamageOnly;

• var – переменная, может принимать различные значения в зависимости от типа;
• const – константа. Не может быть изменена ни из UnrealScript, ни из вне (с помощью внешнего программирования);
• local – используется только внутри функций. Данная переменная существует на этапе исполнения функции, в которой она описана, а потом её значение будет утеряно.

• bool – бинарная переменная для логических опираций. Значения: True/False (Правда/Ложь);
• int – целое значение от –2147483648 до 2147483647 (включая пределы);
• byte – целое значение от 0 до 255 (включая пределы). Значение, которое выходит за эти границы будет заворачиваться.
  Пример: число 256, введённое в переменную типа byte примет значение 0;
• float – вещественное значение, десятичная дробь;
• string – строка символов, заключённых в двойных кавычки;
• name – идентификатор (имя), заключённый в одинарные кавычки. Имена могут содержать только буквы. Цифры и символ подчёркивания.

Регистр букв в именах не имеет значения.

var struct <Имя_структуры> {
<Описание переменной 1>;
< Описание переменной 2>;
…
} <Имя_переменной 1>, <Имя_переменной 2>, …;

var enum <Имя_типа> {
<Значение1>,
< Значение 2>,
…
} <Имя_переменной 1>, < Имя_переменной 2>, …;

EnumCount(<Имя_типа>)

• Булевская переменная Initialized – служебная переменная для проверки корректной работы мутатора (в принципе не обязательна);
• Вещественная переменная LifeStolenPerHit – указывает какой прцент от урона перейдёт в жизнь;
• Целая переменная MaxLife – определяет максимальное количество жизни, которое может быть у игрока (что-бы был лимит вампиризма);
• Булевская переменная bInflictedDamageOnly – если урон, нанесённый жертве больше её жизни и значение этого параметра равно True, то игрок, нанёсший урон получит количество жизни равное жизни жертвы, а если значение параметра равно False, то игрок, нанёсший урон получит количество жизни равное нанесённому урону как бы он ни был велик. В любом случае, после этого жертва умирает.

<Модификаторы_функции> function/event <Тип_функции> <Имя_функции> (<Модификаторы_параметра> <Тип_параметра> <Имя_параметра>, …)
{
…
}

• final – данная функция не может быть перегружена (переопределена – override) в подклассах или состояниях (state) этого класса. Функции, определённые как статические (static) и финальные (final), автоматически считаются симулированными (simulated).
• iterator – данная функция является итерационной функцией (итератором) для использования после ключевого слова foreach.
  • Итераторами могут быть только функции, определённые с помощью внешнего программирования (native).
• latent – данная функция требует определённых затрат времени на выполнение. Латентные функции могут вызываться только из кода состояний (state) или из других латентных функций. Латентные функции должны быть внешними (native).
• native (или intrinsic) – данная функция определена во внешнем С++ коде.
• native(<Номер>) – данная функция находится под указанным номером в С++ коде.
• simulated – данная функция вызывается на сервере и на клиенте при игре по сети. Функции, не определённые как симулированные игнорируются при работе скрипта у клиента.
• singular – данная функция предотвращает самовызов.
• static – данная функция может быть вызвана без экземпляра класса, в котором она описана.
• exec – данная функция может быть вызвана через консоль.

• out – значение переменной, которая будет подставлена в качестве данного параметра может быть изменено в теле функции. Если не ставить out перед описанием параметра и передать в качестве параметра переменную, то функция возьмёт из данной переменной значение, обработает его и возвратит некоторое значение в то место кода, где она (функция) стоит. Если же слово out стоит перед описанием параметра и в качестве параметра передаётся некая переменная, то функция возьмёт значение из этой переменной, запомнит имя переменной, обработает значение, а потом возвратит некоторое значение в то место кода, где она (функция) стоит, но также изменит значение переменной, подставленной в качестве параметра.
  Это можно использовать, когда требуется что бы функция возвращала более одного значения. Возможно моё объяснение путанное и непонятное, но это довольно сложно объяснить человеку, впервые столкнувшемуся с программированием. Для корректного объяснения требуется вводить такие понятия как параметры-переменные и параметры-значения, а также понятие указателя на область памяти. Желательно всё таки знать основы программирования на языках С++ или Pascal;
• optional – данный параметр может быть пропущен при вызове процедуры. Если вы хотите пропустить данный параметр, то запятые всё равно нужны. Просто межлу ними ничего не будет стоять;
• coerce – значение, которое передаётся функции через данный параметр, будет автоматически приведено к указанному типу.

function PostBeginPlay()
{
if (Initialized)
return;
Initialized = True;
Level.Game.RegisterDamageMutator( Self );
}

function MutatorTakeDamage( out int ActualDamage, Pawn Victim, Pawn InstigatedBy, out Vector HitLocation,
out Vector Momentum, name DamageType)
{
if ((InstigatedBy.IsA('Bot') || InstigatedBy.IsA('PlayerPawn')) && (Victim != InstigatedBy) && (InstigatedBy != None) && (Victim != None))
{
if ((Victim.Health < ActualDamage) && bInflictedDamageOnly)
ActualDamage = Victim.Health;
InstigatedBy.Health += ActualDamage * LifeStolenPerHit;

if ((InstigatedBy.Health > MaxLife) && (MaxLife != 0))
{
InstigatedBy.Health = MaxLife;
}
}

if ( NextDamageMutator != None )
NextDamageMutator.MutatorTakeDamage( ActualDamage, Victim, InstigatedBy, HitLocation, Momentum, DamageType );
}

• out int ActualDamage – параметр, определяющий величину нанесённого урона. Величина урона должна быть целым числом (int).Так как параметр описан со словом out, то это означает, что в процедуру через данный параметр будет передано некоторое значение, которое мы можем обработать и изменить, а затем уже оно будет возвращено обратно во внешний код;
• Pawn Victim – параметр, указывающий на обьект, которому был нанесён урон. Это жертва;
• Pawn InstigatedBy – параметр, указывающий на обьект, который нанёс урон жертве. Это подстрекатель;
• out Vector HitLocation – параметр, содержащий вектор, координаты которого определяют координаты точки попадания. Именно в эту точку подстрекатель нанёс урон жертве. Так как параметр описан со словом out, то это означает, что в процедуру через данный параметр будет передано некоторое значение, которое мы можем обработать и изменить, а затем уже оно будет возвращено обратно во внешний код;
• out Vector Momentum – параметр, определяющий вектор отдачи при получении урона жертвой. Так как параметр описан со словом out, то это означает, что в процедуру через данный параметр будет передано некоторое значение, которое мы можем обработать и изменить, а затем уже оно будет возвращено обратно во внешний код;
• name DamageType – параметр, определяющий тип наносимого урона. В соответствии с различными типами урона можно описать различные методы его обработки.

if ((InstigatedBy.IsA('Bot') || InstigatedBy.IsA('PlayerPawn')) && (Victim != InstigatedBy) && (InstigatedBy != None) && (Victim != None))

• Является ли подстрекатель ботом;
• Является ли подстрекатель игроком;
• Не совершила ли жертва суицид;
• Существует ли жертва как объект;
• Существует ли подстрекатель как объект.

Эти проверки нужны для корректной работы мутатора. Если данные условия выполняются, то выполняется следующий отрезок кода:

if ((Victim.Health < ActualDamage) && bInflictedDamageOnly)
ActualDamage = Victim.Health;
InstigatedBy.Health += ActualDamage * LifeStolenPerHit;

if ((InstigatedBy.Health > MaxLife) && (MaxLife != 0))
{
InstigatedBy.Health = MaxLife;
}

if ((Victim.Health < ActualDamage) && bInflictedDamageOnly)
ActualDamage = Victim.Health;
InstigatedBy.Health += ActualDamage * LifeStolenPerHit;

if ((InstigatedBy.Health > MaxLife) && (MaxLife != 0))
{
InstigatedBy.Health = MaxLife;
}

if ( NextDamageMutator != None )
NextDamageMutator.MutatorTakeDamage( ActualDamage, Victim, InstigatedBy, HitLocation, Momentum, DamageType );

[Public]
	Object=(Name=Vampire.Vampire,Class=Class,MetaClass=
	Engine.Mutator,Description="Vampire,You gain life equal to the amount of damage you do to an enemy.")

//===================================
// VampireShell ; This is effect script.
// Description: Red shell around damage instigator.
//===================================

class VampireShell expands Effects;

defaultproperties
{
bAnimByOwner=True
bOwnerNoSee=True
bNetTemporary=False
bTrailerSameRotation=True
Physics=PHYS_Trailer
RemoteRole=ROLE_SimulatedProxy
LODBias=0.500000
DrawType=DT_Mesh
Style=STY_Translucent
Texture=None
ScaleGlow=0.500000
AmbientGlow=64
Fatness=157
bUnlit=True
bMeshEnviroMap=True
LifeSpan=0.500000
}

• bAnimByOwner=True – анимировать в соответствии с движениями владельца. Для того что бы наша оболочка повторяла движения модели игрока;
• bOwnerNoSee=True – невидимый для владельца. Для того что бы игрок не видел оболочку перед глазами;
• bNetTemporary=False – обьект и его переменные устанавливаются только в момент его создания и не подлежат дальнейшей обработке. Всё что обрабатывается клиентской частью не связано больше с сервером. Обычно это свойство устанавливается для классов, которые наследуются от класса Effects, а также других классов, которые существуют независимо (неуправляемые снаряды и т.п.). У нас оболочка как раз управляема (повторяет движения игрока), поэтому - False;
• bTrailerSameRotation=True – поворот такой же как и у владельца. Для того что бы оболочка поворачивалась вместе с игроком;
• Physics=PHYS_Trailer – тип физики. У нас оболочка прикреплена к игроку и её координаты меняются вместе с движением игрока (Trailer от англ. прицеп);
• RemoteRole=ROLE_SimulatedProxy – роль данного обьекта в игровом мире. В данном случае мы ставим такое значение, которое применяется для обьектов, движение которых может быть предсказано;
• LODBias=0.500000 – уровень детализации (LOD - Level of detail). По умолчанию в обьектах стоит 1;
• DrawType=DT_Mesh – способ отрисовки обьекта. У нас трёхмерный обьёмный обьект;
• Style=STY_Translucent – стиль наложения текстур. У нас прозрачная оболочка;
• Texture=None – текстура обьекта. У нас ничего не стоит так как текстура выбирается в коде мутатора (смотрите далее);
• ScaleGlow=0.500000 – в нашем случае прозрачной оболочки (Style=STY_Translucent) это степень прозрачности. Величина данного параметра меняется от 0 до 1. У нас 0.5 – полупрозрачная оболочка;
• AmbientGlow=64 – яркость освещённости. Величина меняется от 0 до 255 (255 = пульсация);
• Fatness=157 – ширина обьекта. По умолчанию 128 и меняется от 0 до 255.
• bUnlit=True – не освещать обьект. У нас источники освещения не освещают, а тени не затеняют оболочку.
• bMeshEnviroMap=True – хромовая поверхность. У нас оболочка с эффектом зеркальной поверхности.
• LifeSpan=0.500000 – время жизни обьекта. Если это значение равно 0, то обьект существует до тех пор пока для него не будет вызван метод Destroy. Если значение отлично от нуля, то игра автоматически удалит обьект по истечении заданного времени в секундах. У нас стоит 0.5 – оболочка будет присутствовать на игроке пол-секунды, после чего исчезнет. 

//===================================
// Vampire ; This is mutator script.
// Description: You gain life equal to the amount of damage you do to
// an enemy.
//===================================

class Vampire expands Mutator;

var bool Initialized;
var vector InstFog;
var float InstFlash;
var VampireShell VampireShellEffect;
var texture ShellSkin;
var class<VampireShell> ShellType;

var() float LifeStolenPerHit;
var() int MaxLife;
var() bool bInflictedDamageOnly;
var() bool bIsRegenEffect;

function PostBeginPlay()
{
if (Initialized)
return;
Initialized = True;
Level.Game.RegisterDamageMutator( Self );
}

function MutatorTakeDamage( out int ActualDamage, Pawn Victim, Pawn InstigatedBy, out Vector HitLocation,
out Vector Momentum, name DamageType)
{
if ((InstigatedBy.IsA('Bot') || InstigatedBy.IsA('PlayerPawn')) && (Victim != InstigatedBy) && (InstigatedBy != None) && (Victim != None))
{
if ((Victim.Health < ActualDamage) && bInflictedDamageOnly)
ActualDamage = Victim.Health;
InstigatedBy.Health += ActualDamage * LifeStolenPerHit;

if (bIsRegenEffect && (MaxLife != 0 ))
{
FlashShell(InstigatedBy);
if ( InstigatedBy.IsA('PlayerPawn') )
PlayerPawn(InstigatedBy).ClientInstantFlash(InstFlash, InstFog);
}

if ((InstigatedBy.Health > MaxLife) && (MaxLife != 0))
{
InstigatedBy.Health = MaxLife;
}
}

if ( NextDamageMutator != None )
NextDamageMutator.MutatorTakeDamage( ActualDamage, Victim, InstigatedBy, HitLocation, Momentum, DamageType );
}

function FlashShell(pawn Other)
{
if (VampireShellEffect == None)
{
VampireShellEffect = Spawn(ShellType, Other,,Other.Location, Other.Rotation);
}
if ( VampireShellEffect != None )
{
VampireShellEffect.Mesh = Other.Mesh;
VampireShellEffect.DrawScale = Other.Drawscale;
VampireShellEffect.Texture = ShellSkin;
}
}

defaultproperties
{
LifeStolenPerHit=1.000000
MaxLife=200
bInflictedDamageOnly=True
bIsRegenEffect=True
InstFog=(X=475.000000,Y=325.000000,Z=145.000000)
InstFlash=-0.400000
ShellSkin=FireTexture'UnrealShare.Belt_fx.ShieldBelt.RedShield'
ShellType=Class'Vampire.VampireShell'
}

var vector InstFog;
var float InstFlash;
var VampireShell VampireShellEffect;
var texture ShellSkin;
var class<VampireShell> ShellType;

var() bool bIsRegenEffect;

if (bIsRegenEffect && (MaxLife != 0 ))
{
FlashShell(InstigatedBy);
if ( InstigatedBy.IsA('PlayerPawn') )
PlayerPawn(InstigatedBy).ClientInstantFlash(InstFlash, InstFog);
}

function FlashShell(pawn Other)
{
if (VampireShellEffect == None)
{
VampireShellEffect = Spawn(ShellType, Other,,Other.Location, Other.Rotation);
}
if ( VampireShellEffect != None )
{
VampireShellEffect.Mesh = Other.Mesh;
VampireShellEffect.DrawScale = Other.Drawscale;
VampireShellEffect.Texture = ShellSkin;
}
}

function actor Spawn
(
class<actor> SpawnClass,
optional actor SpawnOwner,
optional name SpawnTag,
optional vector SpawnLocation,
optional rotator SpawnRotation
);

• SpawnClass – класс, экземпляр которого должен быть вызван;
• SpawnOwner – владелец вызываемого класса. Это значение, которое будет подставлено в свойство Owner вызванного обьекта;
• SpawnTag – значение, которое будет присвоено свойству Tag при создании обьекта;
• SpawnLocation – вектор, определяющий координаты в пространстве, в которые должен быть вызван обьект;
• SpawnRotation – ротатор, который определяет поворот обьекта. Подобно вектору указывает «направление взгляда» обьекта.

VampireShellEffect = Spawn(ShellType, Other,,Other.Location, Other.Rotation);

if ( VampireShellEffect != None )
{
VampireShellEffect.Mesh = Other.Mesh;
VampireShellEffect.DrawScale = Other.Drawscale;
VampireShellEffect.Texture = ShellSkin;
}

bIsRegenEffect=True
InstFog=(X=475.000000,Y=325.000000,Z=145.000000)
InstFlash=-0.400000
ShellSkin=FireTexture'UnrealShare.Belt_fx.ShieldBelt.RedShield'
ShellType=Class'Vampire.VampireShell'